One pin, five buttons

Select, Left, Up, Down and Right all share analog pin A0. Each button puts a different resistor in the path, so analogRead(A0) returns a different value depending on which one is down: roughly 0 for Right, about 100 for Up, 250 for Down, 400 for Left, 640 for Select, and over 1000 when nothing is pressed. The reset button is wired to the board's reset and is not readable.

The read_LCD_buttons() function checks the reading against those thresholds from the smallest up and returns a named button. The values used here are for the v1.1 shield, which is what ships in the pack; a v1.0 board uses slightly different thresholds (in the comment) if Select ever misbehaves.

Cursor positions

lcd.setCursor(column, row) is zero-based: (0, 1) is the start of the second line, (9, 1) is ten characters in. Printing does not clear what was there before, so when the text you print can be shorter than the last thing you printed, pad it with spaces ("RIGHT " not "RIGHT") or you will see leftovers.

The optional LCDKeypad library in the Resources tab does the same job with lcd.button() and adds a debounced lcd.buttonBlocking() for menus.

Read the five buttons

#include <LiquidCrystal.h>

LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

int lcd_key = 0;
int adc_key_in = 0;

#define btnRIGHT  0
#define btnUP     1
#define btnDOWN   2
#define btnLEFT   3
#define btnSELECT 4
#define btnNONE   5

// Thresholds for the v1.1 shield. For a v1.0 shield use:
// <50 RIGHT, <195 UP, <380 DOWN, <555 LEFT, <790 SELECT
int read_LCD_buttons() {
  adc_key_in = analogRead(0);
  if (adc_key_in > 1000) return btnNONE;
  if (adc_key_in < 50)   return btnRIGHT;
  if (adc_key_in < 250)  return btnUP;
  if (adc_key_in < 450)  return btnDOWN;
  if (adc_key_in < 650)  return btnLEFT;
  if (adc_key_in < 850)  return btnSELECT;
  return btnNONE;
}

void setup() {
  lcd.begin(16, 2);
  lcd.setCursor(0, 0);
  lcd.print("Push the buttons");
}

void loop() {
  lcd.setCursor(9, 1);
  lcd.print(millis() / 1000);   // seconds since power-up

  lcd.setCursor(0, 1);
  lcd_key = read_LCD_buttons();

  switch (lcd_key) {
    case btnRIGHT:  lcd.print("RIGHT "); break;
    case btnLEFT:   lcd.print("LEFT  "); break;
    case btnUP:     lcd.print("UP    "); break;
    case btnDOWN:   lcd.print("DOWN  "); break;
    case btnSELECT: lcd.print("SELECT"); break;
    case btnNONE:   lcd.print("NONE  "); break;
  }
}

LCD Keypad Shield: Buttons

One pin, five buttons

Cursor positions