What it does

The two right-hand digits are seconds, the two left-hand digits are minutes. Button 2 adds a minute, button 3 adds a second (both wrap at 60). A short tap on button 1 starts the countdown; holding button 1 resets everything to zero. When it reaches 00:00 the beeper sounds three times.

Short press, long press

This is where the library earns its keep. MFS.getButton() returns codes such as BUTTON_1_SHORT_RELEASE, BUTTON_1_LONG_PRESSED and BUTTON_1_LONG_RELEASE, so one button can do two jobs. Start is triggered on the short release (you do not want it starting while the finger is still down), and reset on the long press.

The counting itself uses the TimerOne library underneath, which is why button handling and display refresh stay smooth even though the loop uses delay().

The sketch below is the library's countdown example, adapted to the pin names in the HERO library.

Countdown timer

#include <TimerOne.h>
#include <Wire.h>
#include <MultiFuncShield.h>

enum CountDownModeValues { COUNTING_STOPPED, COUNTING };

byte countDownMode = COUNTING_STOPPED;
byte tenths = 0;
char seconds = 0;
char minutes = 0;

void setup() {
  Timer1.initialize();
  MFS.initialize(&Timer1);
  MFS.write(0);
  Serial.begin(9600);
}

void loop() {
  byte btn = MFS.getButton();

  if (countDownMode == COUNTING_STOPPED) {
    if (btn == BUTTON_1_SHORT_RELEASE && (minutes + seconds) > 0) {
      countDownMode = COUNTING;            // start
    } else if (btn == BUTTON_1_LONG_PRESSED) {
      tenths = 0; seconds = 0; minutes = 0; // reset
      MFS.write(minutes * 100 + seconds);
    } else if (btn == BUTTON_2_PRESSED || btn == BUTTON_2_LONG_PRESSED) {
      minutes++;
      if (minutes > 60) minutes = 0;
      MFS.write(minutes * 100 + seconds);
    } else if (btn == BUTTON_3_PRESSED || btn == BUTTON_3_LONG_PRESSED) {
      seconds++;
      if (seconds >= 60) seconds = 0;
      MFS.write(minutes * 100 + seconds);
    }
  } else if (countDownMode == COUNTING) {
    if (btn == BUTTON_1_SHORT_RELEASE || btn == BUTTON_1_LONG_RELEASE) {
      countDownMode = COUNTING_STOPPED;    // pause
    } else {
      tenths++;
      if (tenths == 10) {
        tenths = 0;
        seconds--;
        if (seconds < 0 && minutes > 0) {
          seconds = 59;
          minutes--;
        }
        if (minutes == 0 && seconds == 0) {
          MFS.beep(50, 50, 3);             // three beeps
          countDownMode = COUNTING_STOPPED;
        }
        MFS.write(minutes * 100 + seconds);
      }
      delay(100);
    }
  }
}

Multi-Function Shield: Countdown Timer

What it does

Short press, long press